Вежба: Мерење растојања помоћу HC-SR04 сензора и ESP32 платформе

У овој вежби ученици ће научити како да користе HC‑SR04 ултразвучни сензор за мерење растојања до објекта помоћу ESP32 микроконтролера. Добијене вредности биће послате на рачунар преко серијске комуникације и приказане у реалном времену у Processing окружењу.

Вежба повезује рад са сензорима, ESP32 програмирање, серијску комуникацију и визуелизацију података.

ESP32 + HC-SR04

Мерење растојања до препреке помоћу ултразвучног сензора.

Processing визуелизација

Приказ измереног растојања у реалном времену.

📑 Садржај

• Шта је HC-SR04?
• Потребна опрема
• Повезивање компоненти
• ESP32 програм
• Processing програм
• Како систем функционише?
• Могућа проширења
• На шта треба обратити пажњу

Шта је HC-SR04?

HC-SR04 је ултразвучни сензор који служи за бесконтактно мерење растојања. Сензор емитује кратак ултразвучни импулс и мери време које је потребно да се одбијени сигнал врати до пријемника.

Пошто је брзина звука позната, микроконтролер може израчунати растојање до препреке. Овај тип сензора често се користи у роботици, паметним системима паркирања и STEM пројектима.

🧰 Потребна опрема

• ESP32 развојна плоча
• HC-SR04 ултразвучни сензор
• Breadboard плоча
• Повезне жице
• USB кабл
• Arduino IDE
• Processing окружење

Повезивање компоненти

У овој вежби користи се следеће повезивање:

• VCC → 3V3
• GND → GND
• TRIG → GPIO18
• ECHO → GPIO19

ESP32 страна

Приказ прикључака који се користе на ESP32 плочи.

HC-SR04 страна

Приказ прикључака на ултразвучном сензору.

ESP32 програм

// GPIO pin koji pokreće ultrazvučni impuls
int trigPin = 18;

// GPIO pin na kome se prima povratni impuls
int echoPin = 19;

// Promenljiva u kojoj će biti sačuvano
// trajanje povratnog impulsa (u mikrosekundama)
long duration;

// Izračunato rastojanje u centimetrima
float distance;

void setup() {

  // Pokretanje serijske komunikacije
  // Brzina mora biti ista kao u Processing programu
  Serial.begin(115200);

  // TRIG pin je izlaz
  pinMode(trigPin, OUTPUT);

  // ECHO pin je ulaz
  pinMode(echoPin, INPUT);
}

void loop() {

  // Kratak LOW impuls kako bi se senzor resetovao
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);

  // Slanje ultrazvučnog impulsa
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(15);

  // Završetak impulsa
  digitalWrite(trigPin, LOW);

  // Merenje trajanja povratnog impulsa
  duration = pulseIn(echoPin, HIGH);

  // Izračunavanje rastojanja.
  // 0.034 predstavlja brzinu zvuka u cm/µs,
  // a deljenje sa 2 je potrebno zato što
  // talas putuje do prepreke i nazad.
  distance = duration * 0.034 / 2;

  // Slanje izračunatog rastojanja
  // preko serijskog porta.
  // Šalju se dve decimale.
  Serial.println(distance, 2);

  // Kratka pauza između dva merenja
  delay(200);
}

distance = duration * 0.034 / 2

Визуелизација мерења у Processing окружењу

Поред приказа у Serial Monitor-у, измерено растојање може се приказати и графички. Processing прима вредности које шаље ESP32 и приказује хоризонтални индикатор чија се дужина мења у зависности од измереног растојања.

Processing програм

import processing.serial.*;

// Objekat za serijsku komunikaciju
Serial myPort;

// Trenutno izmereno rastojanje
float distance = 0;

void setup()
{
  // Kreiranje prozora
  size(600,250);

  // Prikaz svih dostupnih serijskih portova
  println(Serial.list());

  // Otvaranje prvog pronađenog porta
  // Brzina mora biti ista kao u ESP32 programu
  myPort = new Serial(this,
                      Serial.list()[0],
                      115200);

  // Funkcija serialEvent()
  // pozivaće se kada stigne jedan red teksta
  myPort.bufferUntil('\n');

  textSize(20);
}

void draw()
{
  // Boja pozadine
  background(245);

  // Naslov
  fill(0);
  text("Измерено растојање",40,40);

  // Okvir indikatora
  noFill();
  strokeWeight(2);
  rect(40,80,500,40);

  // Popunjavanje indikatora.
  // Pretpostavlja se da senzor meri
  // do približno 200 cm.
  fill(100,200,255);
  noStroke();

  rect(
        40,
        80,
        map(distance,0,200,0,500),
        40
      );

  // Ispis numeričke vrednosti
  fill(0);
  text("Distance: " + nf(distance,0,2) + " cm",40,170);
}

// Funkcija se automatski poziva
// kada stigne jedan red teksta
void serialEvent(Serial port)
{
  // Čitanje jednog reda
  String data = port.readStringUntil('\n');

  if(data!=null)
  {
    // Uklanjanje znaka novog reda
    data = trim(data);

    // Pretvaranje primljenog teksta u broj
    distance = float(data);
  }
}

Како систем функционише?

Могућа проширења пројекта

• LED сигнализација близине препреке
• Звучно упозорење помоћу buzzer-а
• Приказ графика мерења
• Чување података у CSV датотеку
• Слање података преко Wi‑Fi мреже
• ESP32 веб сервер
• Робот који избегава препреке

⚠️ На шта треба обратити пажњу

• Проверити исправност свих жица.
• Проверити да су GPIO18 и GPIO19 правилно повезани.
• Проверити серијски порт у Processing програму.
• Избегавати лабаве контакте на breadboard плочи.
• Пре покретања проверити целокупно коло.

📚 Додатно учење